Fizzbuzz in brainfuck.
Copy and paste on www.brainfuck.tk to compile.
Copyright Alexandre Beaulne 2012.
ENDING
COMMAND INDEX DESCRIPTION
>++++++++++ 1 Put 10 in cell {1}
[<++++++++++>-]< 0 Put 100 in cell {0}
[ 0 Start of outer loop
> + 1 Put 100 minus i in cell {1}
[->+>+<<]>>[-<<+>>]<< 1 Copy cell {1} in cell {2}
>> +++ < 2 Put 3 in cell {3}
[>[->+>+<<]>[-<<-[>]
>>>[<[-<->]<[>]>>[[-
]>>+<]>-<]<<]>>>+<<[
-<<+>>]<<<]>>>>>[-<<
<<<+>>>>>]<<<<< 2 Divide cell {2} by cell {3}
>[>+>+<<-]>[<+>-]+ 4 if modulo == 0 print fizz
>[<->[-]]<[ 4 if {x==0} construct
>> +++++++ 6 Put 7 in cell {6}
[<++++++++++>-]<. 5 Print F
+++ . 5 Print I
+++++++++++++++++.. 5 Print ZZ
>>>>> + <<<<< 5 Increment cell {10}
<
[-]] 4 end of if construct
>[-]<[-]<[-]<[-]< 1 clean cell {2} to {5}
[->+>+<<]>>[-<<+>>]<< 1 Copy cell {1} in cell {2}
>> +++++ < 2 Put 5 in cell {3}
[>[->+>+<<]>[-<<-[>]
>>>[<[-<->]<[>]>>[[-
]>>+<]>-<]<<]>>>+<<[
-<<+>>]<<<]>>>>>[-<<
<<<+>>>>>]<<<<< 2 Divide cell {2} by cell {3}
>[>+>+<<-]>[<+>-]+ 4 if modulo == 0 print buzz
>[<->[-]]<[ 4 if {x==0} construct
>> ++++++ 6 Put 6 in cell {6}
[<+++++++++++>-]<. 5 Print B
+++++++++++++++++++. 5 Print U
+++++.. 5 Print ZZ
>>>>> + <<<<< 5 Increment cell {10}
<
[-]] 4 end of if construct
>[-]<[-]<[-]<[-]< 1 Clean cell {2} to {5}
>>>>>>>>>[<+>-]<[<+>-] 9
<[<+>-]<[<+>-]<[<+>-] 6
<[<+>-]<[<+>-]< 3 Copy cell {10} in cell {3}
[>+>+<<-]>[<+>-]+ 4 if not multiple of 3 or 5 print num
>[<->[-]]<[ 4 if {x==0} construct
<[-]<< 1 Put 0 in cell {3}
[->+>+<<]>>[-<<+>>]<< 1 Copy cell {1} in cell {2}
>>>++++++++++ 4 Put 10 in cell {4}
[<++++++++++>-]< 3 Put 100 in cell {3}
< 2 Move to cell {2}
[>[->+>+<<]>[-<<-[>]
>>>[<[-<->]<[>]>>[[-
]>>+<]>-<]<<]>>>+<<[
-<<+>>]<<<]>>>>>[-<<
<<<+>>>>>]<<<<< 2 Divide cell {2} by cell {3}
[+++++++++++++++++++
++++++++++++++++++++
+++++++++ . [-]] 2 Print 100s if any
> 3 Move to cell {3}
[->+>+<<]>>[-<<+>>]<< 3 Copy cell {3} in cell {4}
[>> ++++++++++ << [-]] 3 Put 10 in cell {5} if cell {3} is not 0
> 4 Move to cell {4}
[>[->+>+<<]>[-<<-[>]
>>>[<[-<->]<[>]>>[[-
]>>+<]>-<]<<]>>>+<<[
-<<+>>]<<<]>>>>>[-<<
<<<+>>>>>]<<<<< 4 Divide cell {4} by cell {5}
++++++++++++++++++++
++++++++++++++++++++
++++++++ . > 5 Print 10s
++++++++++++++++++++
++++++++++++++++++++
++++++++ . < 4 Print 1s
[-]] 4 end of if construct
>> ++++++++++ . 6 Print new line
>>>> [-] <<<< 6 Clean cell {10}
[-]<[-]<[-]<[-]<[-] 2 Reset cell {2} to {6}
<< - 0 Decrement i
] 0 end of outer loop